Cijfers
een programma voor de Texas Instruments
TI-83 en TI-84 (Plus) grafische rekenmachines

 

Beschrijving

Het programma CIJFERS verwerkt toetsscores tot cijfers en cijfers tot rapportresultaten.
• Ruwe scores, behaald voor repetities, schoolexamens en andere toetsen, worden omgezet in waarderingscijfers of toetscijfers.
• Meerdere toetscijfers leveren een rapportcijfer. Dit komt neer op het berekenen van een gewogen rekenkundig gemiddelde van een getallenreeks.

Toetscijfers

Berekening toetscijfers voor een beperkt aantal scores Voor het omzetten van scores naar cijfers wordt eerst een maximale score gevraagd (bijvoorbeeld 27). Vervolgens moet een score worden ingevoerd (21). Hierna wordt het cijfer getoond (80 of 8,0) en wacht het programma op invoer van een volgende score.

Deze werkwijze is geschikt voor het omzetten van een beperkt aantal scores. Voor grotere aantallen is er een tweede optie: de conversietabel (zie hieronder).

De cijfers worden berekend volgens de standaard-omzetting:
cijfer = 10 + 90 * (score / maximale score).

Toetscijfers - Conversietabel

Toetscijfers voor alle scores (0 tot maximale score 27) De conversietabel geeft de cijfers voor alle scores in afnemende volgorde. De maximale score staat dus bovenaan. Schuif (scroll) met de pijltoetsen (omlaag/omhoog) om de rest van de tabel te zien.
Conversietabel voor maximale score 27

Rapportcijfer

Invoer eerste cijfer van vier Bereken het gewogen rekenkundig gemiddelde van een getallenreeks. Bepaal bijvoorbeeld het voortschrijdend gemiddelde of rapportcijfer van een examenkandidaat voor een bepaald vak met behulp van een reeks wegingsfactoren en de bijbehorende reeks van waarderingen behaald voor repetities, schoolexamens, werkstukken, enz.
De toetscijfers en wegingsfactoren in de tabel hieronder dienen als voorbeeld.
Invoer tweede cijfer van vier
wegingsfactor3455
cijfer (10–100)75806382

Bij het activeren van de optie "Rapportcijfer" vraagt het programma eerst om invoer van het aantal wegingsfactoren (4). Dit is gelijk aan het aantal toetscijfers. Dan volgen de wegingsfactoren (3,4,5,5), telkens gescheiden door ENTER. Voer tenslotte de cijfers (75,80,63,82) op dezelfde manier in.
Gewogen gemiddelde van vier getallen Na invoer van het laatste cijfer verschijnt het gewogen gemiddelde tweemaal in het domein van 10–100 en éénmaal in het domein 1–10:
74,706
75
7.
Aansluitend kan het progamma nieuwe cijferreeksen verwerken waarbij herhaalde invoer van eenzelfde reeks wegingsfactoren niet nodig is.

Bij verwerking van reeksen met meer dan zes toetscijfers zijn niet langer alle ingevoerde gegevens blijvend zichtbaar. Daarom wordt in zulke gevallen het laatst ingevoerde cijfer apart weergegeven en telkens opnieuw ververst. In het voorbeeld hieronder gaat 't om tien cijfers en wegingsfactoren.
Het gewogen gemiddelde en de (niet zichtbare) gegevens kunnen na beëindiging van het programma worden opgevraagd (zolang ze niet door andere toepassingen zijn overschreven).
Gewogen gemiddelde van tien getallen Met de opdracht ALPHA, Z, ENTER wordt het gewogen gemiddelde getoond (in het voorbeeld 76,90697674). Roep de cijfers en wegingsfactoren op met de toetsaanslagen STAT, 1 (1:Edit), of met de opdrachten 2nd, L1, ENTER en 2nd, L2, ENTER. Gebruik zo nodig de pijltoetsen om in horizontale richting te schuiven (scrollen).
Reeksen op het basisscherm Reeksen op het statistiekscherm

Geheugen (memory error)

Het programma CIJFERS neemt ongeveer 2 kilobyte geheugenruimte (RAM) in beslag. De aanmaak van een conversietabel voor de maximale score 53 vraagt circa 1 kb.
Een tekort aan vrije geheugenruimte (zie 2nd,MEM > 2 > RAM FREE) kan de uitvoering van het programma doen afbreken met de foutmelding ERR:MEMORY. Een hoeveelheid vrij geheugen van 3 kilobyte zal het afbreken doorgaans kunnen voorkomen, maar voor productie van grotere conversietabellen is 4 kb nodig.
Als het programma niet normaal wordt afgesloten, door een foutmelding of door een ingreep van de gebruiker, kan een aanzienlijke hoeveelheid geheugenruimte in gebruik blijven. Geef het geheugen zo weer vrij: start het programma opnieuw op, maak een (kleine) conversietabel en sluit normaal af. Of verwijder matrix [A] handmatig.

 

Programmalijst

[ Opmerking ]
PROGRAM:CIJFERS
"Mem [A],L1-L3,I,M,N,S,Z"
"ver200411a"
[ geheugengebruik, versie ]
Normal:Float
Full
Lbl 0
ClrHome
Menu(" Cijfers ","Toetscijfers",1,"Rapportcijfer",2,"Hulp,info",3,"Stop",4)

Lbl 1
Disp "Bereken toets-","cijfers volgens",""
Disp "Cijfer=10+90*S/M","S=score","M=max.score"
Output(8,15,">>")
Pause
ClrHome
Disp "10+90*S/M",""
Disp "Maximale score?"
Input "M? ",M
max(M,1)→M
M→S
ClrHome
Disp "Aantal om te","zetten scores?"
Disp "1: Weinig","2: Alle (tabel)"
0→Z
While Z=0
getKey→Z
End
ClrHome
If Z=93
Goto 1B
Disp "","","",""
While (S>0) and (S≤M)
Output(6,1,"(0:Stop)")
Input "Score? ",S
ClrHome
Disp M,S,round(10+90S/M,0),""
Output(1,7,"Max.sc.")
Output(2,7,"Score")
Output(3,7,"Cijfer")
End
Goto 0
Lbl 1B
int(M/2+1)→N
{N,4}→dim([A])
For(Z,1,4,2)
For(I,1,N)
S→[A](I,Z)
round(10+90S/M,0)→[A](I,Z+1)
max(0,S–1)→S
End
End
If N>7
Then
Disp "Schuiven: pijl","omlaag/omhoog.",""
Disp "Stoppen: ENTER"
Output(8,15,">>")
Pause
ClrHome
End
Output(8,15,">>")
Pause [A]
DelVar [A]
Goto 0

Lbl 2
Disp "Bereken gewogen","gemiddeld cijfer"
Disp "van toetscijfers",""
Disp "Geef het AANTAL","wegingsfactoren","(aantal toetsen)"
Input "Aantal? ",N
ClrHome
N→dim(L2)
N→dim(L1)
Fill(0,L2)
Disp "Geef de","wegingsfactoren","(1e,ENTER,enz.)"
For(I,1,N)
Input "Factor? ",Z
Z→L2(I)
End
Lbl 2A
ClrHome
Fill(0,L1)
Disp "Wegingsfactoren:",L2
Disp "Geef de cijfers","(domein:10-100)",L1
For(I,1,N)
Input "Cijfer? ",Z
If Z<10
Then
Disp "Cijfer<10.","Zie Hulp. >>"
Pause
End
Z→L1(I)
ClrHome
Disp "Weging,cijfers:",L2,L1,""
If N>4
Output(4,14,Z)
End
L1*L2→L3
sum(L3)/sum(L2)→Z
0→dim(L3)
Disp "Gemiddelde:"
Output(6,6,round(Z,3))
Output(7,6,round(Z,0))
Output(8,7,round(Z/10,0))
Output(8,15,">>")
Pause
Menu("","Nieuwe cijfers",2A,"Menu",0)

Lbl 3
Disp "Rapport","Cijferdomein:","10 (0) - 100."
Disp "Voer bijv.","7,8 in als 78","(0,5 als 5)."
Output(8,15,">>")
Pause
ClrHome
Disp "RAM nodig voor","pgm: ca.2 kbyte.","Toets, optie 2:"
Disp "extra: 1 kb (bij","max.score 53).","","info:"
Output(8,1,"www.tenhorn.com")
Output(7,15,">>")
Pause
Goto 0

Lbl 4
Stop

 

Volg de link voor een praktische oefening in het programmeren van je rekenmachine: Creating a Program for the TI calculator

 

Hein ten Horn
Top | Programs Texas Instruments | Home