Het instellen van twee BT modules is lastig. Bluetooth werkt echter bijzonder goed zodra alles correct ingesteld is! Om de HC-05 (of HC-06) in te stellen moet je zogenaamde AT commando's opsturen. Dat kun je gewoon met een zelfgemaakte sketch doen. Hieronder staat hoe je alles aan de praat kunt krijgen. Helaas geven sommige fabrikanten hun HC-05 afwijkende eigenschappen, waardoor het soms net iets anders moet. Ook kan het zijn dat de modules al gebruikt zijn en niet meer op de fabrieksinstellingen staan. In het laatste geval zit er niet veel andere dan een aantal instellingen (met name de baudrate) uit te proberen.
Om te beginnen moet je de een HC-05 instellen als master en de ander als slave. De master kan een verbinding leggen met een willekeurige HC-05 of met een specifieke HC-05. Ik heb voor het laatste gekozen omdat dat betrouwbaarder is.

• Upload het programma dat je hier beneden ziet, zonder dat de modules zijn aangesloten; koppel daarna de Arduino los.
• Neem een van de twee HC-05 modules. Deze wordt de slave wordt: dat is standaard al zo ingesteld.
• Sluit deze HC-05 aan: TX op digitale pin 2, RX op pin 3, pin EN op VCC en uiteraard GND op GND. VCC mag 3,3 of 5 volt zijn. Eigenlijk moet je voor RX een spanningsdeler zetten, zodat die pin maar 3,3 volt krijgt. Als je niet te lang met de module bezig bent, dan kun je deze (op eigen risico) op 5 volt aansluiten.
• Als het goed is knippert het lampje van de HC-05 nu langzaam. Als dat zo is, dan staat de HC-05 in commando modus en is de baudrate 38400. Als het lampje snel knippert dan staat hij in data modus, maar wellicht lukt het toch AT commando's te verzenden met 9600 baud.
• Verstuur AT via de seriële monitor. Het voorbeeldprogramma maakt automatisch hoofdletters van commando's. De module zal OK terugsturen, zo niet dan is er iets mis. Als je ERROR(0) terugkrijgt dan is een ongeldig commando ingetypt, maar is de rest wel goed. Als je niets terugkrijgt dan moet je andere baudrates, wel of geen regeleinden en dergelijke uitproberen (zie het commentaar in de sketch).
• Vraag nu het adres op door AT+ADDR te verzenden. Je krijgt het adres te zien. Dit heb je straks nodig, dus noteer het of maak een schermafdruk, zie mijn schermafdruk op deze pagina.
• Koppel de Arduino en de HC-05 los en sluit de andere HC-05 aan.
• Typ in: AT+ROLE=1 (de HC reageert met OK) 1 = deze HC-05 is nu de master
• Typ in: AT+CMODE=0 (de HC-05 reageert met OK), 0 = verbind met specifieke HC
• Typ in: AT+BIND=98D3,31,F593A1 (maar dan met het adres dat jij eerder van de slave hebt gekregen. Merk op dat de dubbele punten vervangen zijn door komma's!

Je kunt nog veel meer instellen, zoals de naam van de module, het password en de baudrate, maar als je hierbij een fout maakt dan kan het lastig zijn de module weer goed te krijgen. Je kunt de module nu loskoppelen. Hieronder vind je het programma waarmee je de AT commando's kunt geven.

#include <SoftwareSerial.h>
// Programma om AT commando's te geven aan de Bluetooth modules HC-05 en HC-06
SoftwareSerial AT(2, 3); // Sluit pin 2 aan op TX van de HC; sluit pin 3 aan op RX van de HC
// Je mag ook andere pinnen kiezen, verander dat dan in de vorige regel

void setup() {
  /* Hieronder zie je drie keer AT.begin(), met verschillende baudrates
     Dit zijn veel gebruikte baudrates van de HC-05 en HC-06 modules.
     Je moet er een kiezen. Haal hiertoe de commentaarstrepen bij de juiste regel weg en zorg
     dat bij de ander twee regels wel commentarstrepen staan.
     Bij de HC-05 moet je de Enable pin aan VCC VOOR opstarten,
        bij gewoon gebruik mag je deze aansluiting laten zweven of met GND verbinden.
        Als de HC-05 langzaam knippert, dan staat hij in commando modus en is de baudrate 38400
        Als de HC-05 snel knippert, dan staat hij in data mode,
        maar kun je wellicht toch AT commando's geven bij een baudrate van 9600

      Bij sommige instellingen verandert de baudrate van de HC module.
      Als dat gebeurt, upload dit programma dan opnieuw met de nieuwe baudrate.

      Begin met een baudrate van 9600 of 38400 (zie boven), met de seriele monitor ingesteld op "Zowel NL als CR" en 9600 baud.
      Als je AT opstuurt dan moet de HC antwoorden met OK.
      AT en andere commando's gebruiken hoofdletter; dat wordt in dit programma automatisch gedaan.
      Als je geen OK ziet probeer dan eerst de monitor in te stellen op "Geen regeleinde".
      Als het nog niet lukt probeer dan een andere baudrate.
      Helaas maken de verschillende fabrikanten nogal eens andere, niet of nauwelijks gedocumenteerde keuzes waardoor je
      soms lang aan het proberen bent voordat je OK ziet.
      Als het nog steeds niet lukt:
      Controleer eerst of de aansluitingen TX en RX niet per ongeluk zijn omgewisseld.
      Als de module al eerder is geconfigureerd dan kan het zijn dat er nog een andere baudrate is ingesteld.
  */

  //  AT.begin(9600);
  AT.begin(38400);
  // AT.begin(115200);
  Serial.begin(9600);
  Serial.println("Typ een AT commando en verzend dat..");
}

void loop() {
  if (AT.available() > 0) Serial.write(AT.read());
  if (Serial.available()) {
    char C = Serial.read();
    if ( (C >= 'a') && (C <= 'z') ) C -= 32; // Maak van kleine letters hoofdletters
    AT.write(C);
  }
}

Hoe gebruik je nu de BT modules?

Sluit de HC-05 aan op twee verschillende Arduino's. Zodra beide Arduino's aan staan moeten de ledjes op de HC-05 na enige tijd uitgaan. Als dat zo is, dan zijn ze gekoppeld. Open het testprogramma dat je hieronder vindt en laad dat in EEN van beide Arduino's en open de Seriële monitor. In de eerste regel zie je het adres staan van de chip die de Arduino gebruikt. Dat geeft de mogelijkheid om de Arduino's een unieke naam te geven, terwijl je maar &ecaute;&ecaute;n programmaversie nodig hebt. Je moet het adres dat jouw Arduino teruggeeft nu kopiëren (selcteren in de monitor en CTR-C intypen). Het adres wordt zo geprint dat je dit rechtstreeks kunt overnemen in jouw sketch (zie de blauwe regel in de schermafdruk). Vervang alles wat achter byte Naam1[10] = staat door deze regel. Als je dit fout doet, dan heten beide Arduino's "Arduino 2". Mocht je dit ingewikkeld vinden of werkt dit bij jou niet omdat jouw Arduino een afwijkende chip heeft, dan kun je ook twee versies gebruken, met daarin twee vaste namen. Je kunt de sketch dan nog wat vereenvoudigen. Als je het adres gekopieerd hebt, run het programma dan nog een keer en kijk of de Arduino als naam "Arduino 1" teruggeeft.
Belangrijk is nu dat je de Arduino IDE nog een keer opstart. Op die manier kun je twee seriële monitors tegelijk open hebben en het voorkomt ook andere problemen. Geef de juiste poort op (van de tweede Arduino) en laad het programma. Als het goed is komen op beide monitors de identificatiecode van de Arduino's en hun naam. Je kunt nu in een van beide monitors een tekst invoeren en verzenden. Deze wordt door de andere ontvangen en afgedrukt. Werkt erg goed! Nog een punt: omdat ik de baudrate niet heb aangepast is deze 9600 baud. Je kunt de Bluetooth met een veel hogere baudrate gebruiken. Hiervoor moet je vooraf een AT commando gebruiken. Hogere baudrates zijn alleen nodig als je veel data heen en weer stuurt in zeer korte tijd, maar dat is bij deze toepassing niet nodig. Hieronder staat het voorbeeld programma, waarmee je vooral controleert of de verzonden boodschappen goed aankomen.

#include <SoftwareSerial.h>
#include <avr/boot.h>    // Alleen nodig als je de ID van de chip wil lezen
SoftwareSerial BT(2, 3); // Sluit pin 2 aan op TX van de HC; sluit pin 3 aan op RX van de HC
// Je mag ook andere pinnen kiezen, verander dat dan in de vorige regel
byte ID[10];
byte Naam1[10] = {0x59, 0x36, 0x36, 0x32, 0x38, 0x37, 0xFF, 0x0F, 0x22, 0x18}; // Zet hier jouw adres
byte Naam;

void setup() {
  BT.begin(9600);
  Serial.begin(9600);
  for (byte i = 0; i < 10; i++) ID[i] = boot_signature_byte_get(i + 14);
  Serial.print("{"); for (byte i = 0; i < 10; i++) {
    Serial.print("0x");
    Serial.print(ID[i], HEX);
    if (i < 9) Serial.print(",");
    else Serial.println("};");
  }
  if ( memcmp(ID, Naam1, 10) == 0 ) Naam = 1; else Naam = 2;
  Serial.print("Ik ben Arduino "); Serial.println(Naam);
  Serial.println("Typ een commando en verzend dat..");
  Serial.println("Ontvangen: ");
}

void loop() {
  if (BT.available() > 0) Serial.write(BT.read()); // Bericht van andere Arduino
  if (Serial.available()) {
    byte C = Serial.read();
    BT.write(C);
  }
}