Temperatuur sensoren

1. Transistor temperatuursensoren (gewoon of met 1-Wire protocol)
2. Thermistors ofwel NTC-weerstanden (NTC = Negatieve Temperatuur Coëfficiënt)
3. IC's ("kaal" of op een breakout board of de TC74 I²C sensor)
4. Thermokoppels

Transistor

Gewone temperatuurtransistor

Klik hier om de testprogramma's te zien

// Temperatuurmeting met de TMP36
void setup() {
  Serial.begin(9600);
}

void loop() {
  int waarde = analogRead(A0);
  double graden = 500.0 * (waarde / 1024.0) - 50.0; // 750 mV = 25 graden Celsius
  Serial.print("De temperatuur is "); Serial.print(graden); Serial.print(" ");
  Serial.print(char(0xC2)); Serial.print(char(0xB0)); Serial.println("C");
  delay(500);
}

// Temperatuurmeting met de LM35
void setup() {
  Serial.begin(9600);
  analogReference(INTERNAL); // Bij de Arduino Mega gebruik je INTERNAL1V1
}

void loop() {
  int waarde = analogRead(A0);
  double graden = 110.0 * (waarde / 1024.0);
  Serial.print("De temperatuur is "); Serial.print(graden, 1); Serial.print(" ");
  Serial.print(char(0xC2)); Serial.print(char(0xB0)); Serial.println("C");
  delay(500);
}

Transistor met 1-Wire protocol (DS18B20 "Dallas")

De waterdichte uitvoering

Mijn sensor in een waterkoker...

Klik om mijn versie van de sketch te zien  

#include <OneWire.h>
#include <DallasTemperature.h>
#define OW_Pin 2 // Sluit de 1-Wire draad aan op pin 2
OneWire oneWire(OW_Pin); // Maak een object dat met een willekeurig 1-Wire apparaat kan communiceren
DallasTemperature sensors(&oneWire); // Geef dat object door aan "sensors"

void setup(void) {
  Serial.begin(9600);
  sensors.begin();
}

void loop(void) {
  sensors.requestTemperatures(); // Dit commando gaat naar alle sensoren op de 1-Wire bus
  Serial.print("Temperatuur: ");
  Serial.print(sensors.getTempCByIndex(0)); // ByIndex(0): kies de eerste sensor (er mogen er meer zijn)
  Serial.println(" C");
  delay(1000);
}

NTC-weerstand (thermistor)

Thermistor KY-013 op breakout board

Klik hier om het testprogramma te zien

// NTC thermometer op Breakout Board
#define T_PIN A0 // Sluit de analoge uitgang van de sensor aan op de hier genoemde pin (hier A0)

void setup () {
  Serial.begin(9600);            
}

void loop() {
  int digitale_waarde = analogRead(T_PIN); // lees de digitale waarde
  double temp_C = thermistor(digitale_waarde);
  Serial.print("Gemeten temperatuur: ");
  Serial.print(temp_C, 1); Serial.println(" C");       
  delay(1000);
}

double thermistor( int dig_waarde ) { // deze functie corrigeert voor het niet-lineaire verband tussen spanning en temperatuur
  double temp = log( 10000.0 / ( 1024.0 / dig_waarde - 1 ));
  temp = 1 / ( 0.001129148 + ( 0.000234125 * temp ) + ( 0.0000000876741 * pow(temp, 3) ) );
  return temp - 273.15;  
}

IC thermometer DS1620

Meting temperatuur in de diepvrieskast

Klik hier om het testprogramma te zien

/*
  DS1620 Gebaseerd op een voorbeeld van Ruben Laguna
  Sluit als volgt aan:
  Arduino     DS1620
   pin 3  <->  RST (pootje 3)
   pin 4  <->  CLK (pootje 2)
   pin 5  <->  DQ  (pootje 1)
*/
#define rstPin 3
#define clkPin 4
#define dqPin  5

void setup() {
  pinMode(rstPin, OUTPUT);
  pinMode(clkPin, OUTPUT);
  pinMode(dqPin, OUTPUT);
  Serial.begin(9600);
}

void loop() {
  rst_laag();
  clk_hoog();
  rst_hoog(); //
  writeCommand(0x0c); //
  writeCommand(0x02); //
  rst_laag();
  delay(200); // geef de chip even de tijd...

  clk_hoog();
  rst_hoog();
  writeCommand(0xEE); // start conversie
  rst_laag();
  delay(200);

  clk_hoog();
  rst_hoog();
  writeCommand(0xAA);
  float temperatuur = leesTemperatuur();
  rst_laag();
  Serial.print("Temperatuur: "); Serial.print(temperatuur, 1); Serial.print(" ");
  Serial.print(char(0xC2)); Serial.print(char(0xB0));
  Serial.println("C");
  delay(200);
}

void writeCommand(int command) { // zend 8 bit commando naar DQ, minst belangrijke bit eerst
  for (int n = 0; n < 8; n++) {
    int bit = ( (command >> n) & 1 );
    bit_uit(bit);
  }
}

float leesTemperatuur() {
  int8_t data = 0; // Dit moet uin8_t zijn zodat negatieve waarden automatisch goed gaan
  float halfC;
  pinMode(dqPin, INPUT); // DQ moet nu input worden
  for (int n = 0; n < 9; n++) {
    clk_laag();
    int bit = digitalRead(dqPin);
    clk_hoog();
    if (n == 0) {
      if (bit == 1) halfC = 0.5; else halfC = 0; 
      continue;
    }
    data += bit << (n - 1);
  }
  pinMode(dqPin, OUTPUT);
  float Temperatuur = data + halfC;
  return Temperatuur;
}

void bit_uit(int bit) {
  digitalWrite(dqPin, bit); // Zet de bit klaar
  clk_laag();               // geef een klokpuls
  clk_hoog();
}

void clk_hoog() {
  digitalWrite(clkPin, HIGH);
}

void clk_laag() {
  digitalWrite(clkPin, LOW);
}

void rst_hoog() {
  digitalWrite(rstPin, HIGH);
}

void rst_laag() {
  digitalWrite(rstPin, LOW);
}

MCP9808 breakout board

Nauwkeurige thermometer; eenvoudig aan te sluiten

#include "Adafruit_MCP9808.h"

Adafruit_MCP9808 Sensor = Adafruit_MCP9808();

void setup() {
  Serial.begin(9600); // Zet in de volgende regel een ander adres als je het adres hebt veranderd met A0 t/m A2 van de sensor
  if (!Sensor.begin(0x18)) {
    Serial.println("De sensor is niet gevonden. Controleer de aansluitingen en het adres");
    while (1); // Wacht tot de Arduino opnieuw wordt opgestart
  }
}

void loop() {
  Serial.print("Temperatuur: "); Serial.print(Sensor.readTempC(), 1); Serial.print(" "); Serial.print(char(0xC2)); Serial.print(char(0xB0)); Serial.println("C");
  delay(1000);
}

Sensor in de diepvrieskast..

LM75A breakout board

Aansluitingen v.l.n.r.
VCC, SDA, SCL, OS, GND

TC74 sensor (TC740A0 t/m TC74A7)
Ook getest met de Wemos mini D1 ESP32

De TC74 chip

// Demo programma voor de TC74Ax temperatuur sensor
// Kies het juiste adres:
// TC74A0: 0x48; TC74A1: 0x49; TC74A2: 0x0A; TC74A3: 0x0B;
// TC74A4: 0x0C; TC74A5: 0x0D; TC74A6: 0x0E; TC74A7: 0x0F
#define adres 0x4A // Dit werkt dus alleen met de TC74A2
#include <Wire.h>
void setup() {
  Wire.begin();
  Serial.begin(9600);
}

void loop() {
  Wire.write(0);
  Wire.requestFrom(adres, 1);
  if ( Wire.available() ) {
    int8_t Temperatuur = Wire.read(); // int8_t zorgt ervoor dat temperaturen onder nul automatisch goed gaan
    Serial.print("Temperatuur: "); Serial.print(Temperatuur); Serial.println(" C");
  }
  else Serial.println("Kan de temperatuur niet bepalen. Controleer de aansluitingen.");
  delay(500); // Zet hier het delay dat je nodig hebt
}

Thermokoppel

#include "max6675.h"
#define SO 4
#define CS 5
#define CLK 6

MAX6675 thermokoppel (CLK, CS, SO);

void setup() {
  Serial.begin(9600);
  Serial.println("Temperatuur volgens het thermokoppel:");
}

void loop() {
  Serial.print("T = "); Serial.print(thermokoppel.readCelsius(), 1);
  Serial.print(" C of ");
  Serial.print(thermokoppel.readFahrenheit(), 1); Serial.println(" F");
  delay(1000);
}

Combinaties

Temperatuur en vochtigheid (DHT11)
Ook getest met de Wemos mini D1 ESP32 met datapin naar D4

Drie uitvoeringen van de DHT11

Klik hier om het testprogramma te zien

import dht
from machine import Pin
from time import sleep

sensor = dht.DHT11(Pin(4))

while True:
    sensor.measure()
    print(f'De temperatuur is {sensor.temperature()} \u00b0C')
    print(f'De luchtvochtigheid is {sensor.humidity()} %')
    sleep(2)

De uitvoer van het voorbeeldprogramma

Temperatuur, druk en hoogte BMP085, BMP180 of BMP280

#include <Adafruit_BMP085.h>

Adafruit_BMP085 sensor;

void setup() {
  Serial.begin(9600);
  if (!sensor.begin()) {
    Serial.println("De sensor is niet gevonden. Controleer de aansluiting.");
    while (true); // Wacht tot het programma opnieuw wordt opgestart
  }
}

void loop() {
  Serial.print("Temperatuur: "); Serial.print(sensor.readTemperature()); Serial.println(" graden C");
  Serial.print("Druk = "); Serial.print(sensor.readPressure()); Serial.println(" Pa");
  Serial.print("Hoogte boven zeeniveau: ");
  Serial.print(sensor.readAltitude(101700)); // vul hier de werkelijke druk in (1017 hPa = 101700 Pa)
  Serial.println(" meter");
  Serial.println();
  delay(1000);
}